msgbartop
Various ramblings-on, mostly about Red5
msgbarbottom

17 Jan 12 Android Market

I have created pro version of my broadcaster app for Android and Blackberry (playbook). The pro version allows for FMS or Red5 authentication as well as selection of all available cameras / microphones. The next two things I’ll be adding are i10n/i18n and h.264; the latter may not be possible in mobile air but I’ll give it a go.

Pro: https://market.android.com/details?id=air.org.gregoire.mobile.BroadcasterPro

Free: https://market.android.com/details?id=air.Broadcaster

The free version probably won’t be seeing any updates since I hate working on it in Flash CS5.

Lastly, If there’s enough interest I’ll do a version for iOS.

Update 1/18/12

I got h264 publish working in Android last night! woot! What a pain that was.. I need to verify that all is well with the stream data and my modifications to the application then I’ll put the update in the market.

Update #2 1/18/12

The latest pro build is up on the market 1.0.3, it allows you to stream h.263 or h.264 from your Android device. Enjoy!

 

Tags: , , , , , , , ,

08 May 09 Flash on Tap: Red5 Workshop

FOT is coming up real soon… I’m co-presenting with Dominick for the Red5 workshop and I would like to know what you guys want to see? Since its an all-day thing, I would be glad to get some input from the community. Post your ideas as comments.

Tags: , , , , ,

23 Jan 09 The dreaded 2044 error

For those of us who have encountered this error, we can understand each others pain. I searched all around and never found a solution to my particular situation. I found Renaun’s post helpful but it didn’t resolve my issue, as well as these other posts:

http://renaun.com/blog/2007/07/21/226/

http://www.lonhosford.com/lonblog/2008/03/13/flex-liveconnection-and-legacy-flash-swfs/

http://blog.kazumakzak.com/2008/11/26/flex-actionscript-project-sandbox-error-error-2044/

So here is how this all came about – I had built an AIR application using FlexBuilder, which created a LocalConnection to listen for events from a Native (C++) Windows application. The error would occur when the native application was executed prior to starting the AIR application. I tried everything to catch the error and prevent the dialog from appearing; in FlexBuilder this was especially annoying because the dialog would popup behind the IDE before the application window was visible and prevent it from becomming visble until the dialog was closed. I tried creating the LocalConnection on the following events of WindowedApplication:

initialize

addedToStage

applicationComplete

windowComplete

None of which worked, this is also the order in which these event fire by-the-way. So as a last resort, I tried the “preloader” option and BINGO! The preloader runs just before the application so it is able to catch the events comming from the native application, since it would appear that Flash starts listening too early (in my case). Now on to the code…

Add the preloader attribute to the top of your application mxml

preloader="org.gregoire.Preloader" 

Preloader.as

package org.gregoire {

	import org.gregoire.event.*;
	import org.gregoire.net.*;

	import mx.preloaders.DownloadProgressBar;	

	public class Preloader extends DownloadProgressBar {   

		private var localCon:CustomLocalConnection;
		private var srcWidth:int;
		private var srcHeight:int;		

		public function Preloader() {
			super();
			trace("Preload");
			try {
				//create local connection to provide capture source dimensions
				localCon = new CustomLocalConnection("_myBrowser");
				//setup event listeners for changes on the capture source
				localCon.addEventListener(SourceEvent.CHANGED, sourceEventHandler);
			} catch(e:Error) {
				trace("Error with (preloader) LC: " + e);
			}
		}

		private function sourceEventHandler(event:SourceEvent):void {
			trace("Preloader Source change event: " + event);
			srcWidth = event.getWidth();
			srcHeight = event.getHeight();
		}		

		public function hasDimensions():Boolean {
			return (srcWidth > 0 && srcHeight > 0);
		}

		public function getSourceWidth():int {
			return srcWidth;
		}

		public function getSourceHeight():int {
			return srcHeight;
		}

		public function unregister():void {
			localCon.removeEventListener(SourceEvent.CHANGED, sourceEventHandler);
			localCon.close();
			localCon = null;
		}

	}

}

CustomLocalConnection.as

package org.gregoire.net {

    import flash.net.LocalConnection;
    import flash.events.StatusEvent;
    import flash.events.SecurityErrorEvent;
    import org.gregoire.event.SourceEvent;

    public class CustomLocalConnection extends LocalConnection {

        public function CustomLocalConnection(connectionName:String) {
            try {
            	super();
                addEventListener(StatusEvent.STATUS, onStatus);
                addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);

                allowDomain("*");
				client = this;
                connect(connectionName);

            } catch (error:ArgumentError) {
                // server already created/connected
            }
        }

        public function onSourceSelect(sourceName:String):void {
            trace("onSourceSelect called: " + sourceName);
            var evt:SourceEvent = new SourceEvent();
            evt.setSourceName(sourceName);
            dispatchEvent(evt);
        }

        public function onSize(dimension:String):void {
            trace("onSize called: " + dimension);
            //split the dimension string into width and height
            var arr:Array = dimension.split("|", 2);
            if (arr.length >= 2) {
	            var evt:SourceEvent = new SourceEvent();
            	evt.setWidth(parseInt(arr[0]));
            	evt.setHeight(parseInt(arr[1]));
            	dispatchEvent(evt);
            } else {
            	trace("Dimension could not be properly parsed");
            }

        }

		private function onStatus(event:StatusEvent):void {
			trace("LC event: " + event);
			switch (event.level) {
               case "status":
                   trace("LocalConnection.send() succeeded");
                   break;
               case "error":
                   trace("LocalConnection.send() failed");
                   break;
        	}
		}

		private function onSecurityError(e:Error):void {
			trace("LC error: " + e);
		}		

    }
}

SourceEvent.as

package org.gregoire.event {

	import flash.events.Event;

	public class SourceEvent extends Event {

		public static const CHANGED:String = "sourceChanged";

		private var sourceName:String;
		private var width:int;
		private var height:int;

		public function SourceEvent() {
			super(CHANGED);
		}

        public function getSourceName():String {
        	return sourceName;
        }

        public function setSourceName(sourceName:String):void {
        	this.sourceName = sourceName;
        }

        public function getWidth():int {
        	return width;
        }

        public function setWidth(width:int):void {
        	this.width = width;
        }

        public function getHeight():int {
        	return height;
        }

        public function setHeight(height:int):void {
        	this.height = height;
        }

        // Override the inherited clone() method.
        override public function clone():Event {
            return new SourceEvent();
        }

		override public function toString():String{
			return "[SourceEvent] sourceName="+sourceName+",width="+width+",height="+height;
		}

	}
}

I cannot release more than that at this time, but I will try to provide more later if possible. This information should be enough to get you past the 2044 error.

Tags: , , , ,

12 Sep 08 RTMP load tester

I want to let everyone know about a simple RTMP load testing tool that I wrote in flex. Its really simple and allows you to rip a stream from either FMS or Red5 as quickly as possible. If you find it useful or want to add to it, let me know.

The source link is for the latest version in which I have started adding shared object testing; I could use some assistance with that part if any of you have time. The bin link is to the “old” version.

Tags: , , , ,

21 Aug 08 Flash on Tap

Welcome fellow Red5, Flash, and Flex people! I want to let you all know that I will be conducting a workshop on Red5 with Dominick at the Flash on Tap conference in Boston during the second week of October 2008. For those of you that prefer face-to-face of one-on-one time with our core developers, this would be your opportunity – don’t miss out!

http://www.flashontap.com/fot/index.html

Plus I’m pretty sure this is the “first” flash conference + beer festival. It’s ok if you dont drink, just come for all the flash-ing  heh heh

Tags: , , , , ,


Fatal error: Call to undefined function akismet_counter() in C:\xampp\htdocs\paulgregoireblog\wp-content\themes\googlechrome\footer.php on line 9